root/trunk/antimatter/tim/Modules/SFLC/TimeTracker/Output/DeleteEntry.pm

# Copyright (C) 2006   Software Freedom Law Center, Inc.
#  Author: Bradley M. Kuhn <bkuhn@softwarefreedom.org>
#
#  This software gives you freedom; it is licensed to you under version
#  3 of the GNU Affero General Public License.
#
#  This software is distributed WITHOUT ANY WARRANTY, without even the
#  implied warranties of MERCHANTABILITY and FITNESS FOR A PARTICULAR
#  PURPOSE.  See the GNU Affero General Public License for further
#  details.
#
# You should have received a copy of the GNU Affero General Public
# License, version 3 along with this software.  If not, see
# <http://www.gnu.org/licenses/>.
package SFLC::TimeTracker::Output::DeleteEntry;

use strict;
use warnings;

use base qw(SFLC::TimeTracker::Output::Entry);

use Lingua::EN::Inflect qw ( PL);
use Date::Manip;
use Carp;

sub getDatabase {
  return $SFLC::TimeTracker::Input::DATABASE;
}
###############################################################################
sub new {
  my($class) = shift;
  my %input = @_;

  $input{status} = 'DELETED' unless defined $input{status};
  $input{type} = 'abandoned' unless defined $input{type};
  if (defined $input{entries}) {
    $input{object} = $input{entries};
  } elsif (defined $input{entry}) {
    $input{entries} = [ $input{entry} ];
  } else {
    $input{object} = [] unless defined $input{object};
  }

  my %save;
  foreach my $field (qw/userHandle date/) {
    croak "DeleteEntry instance needs $field" if not defined $input{$field};
    $save{$field} = $input{$field};
    delete $input{$field};
  }
  my $self = SFLC::TimeTracker::Output::Entry::new($class, %input);

  foreach my $field (keys %save) {
    $self->set($field => $save{$field});
  }

  return $self;
}
###############################################################################
sub get {
  my($self, $field) = @_;
  if ($field =~ /^(?:entries)$/) {
    # Be smart here.  First, see if the entry is in the database.  If it is,
    #  We want the freshest version of it we can.  It could have been deleted
    #  subsequent to the creation of this objec, however, so we have to 
    #  sometimes use the cached version.
    my $obj = $self->SUPER::get('object');
    my @returnEntries;
    foreach my $cachedEntry (@{$obj}) {
      my $dbEntry =
        $self->getDatabase()->getEntryById($cachedEntry->{userHandle},
                                           $cachedEntry->{id});
      push(@returnEntries, , (defined $dbEntry and ref $dbEntry) ? $dbEntry
           : $cachedEntry);
    }
    return \@returnEntries;
  } elsif ($field =~ /^(?:userHandle|date)$/) {
    return $self->{$field};
  } elsif ($field =~ /^(?:entry)$/) {
    confess "entry is not valid for this class, use entries";
  } else {
    return $self->SUPER::get($field);
  }
}
###############################################################################
sub set {
  my($self, $field, $value) = @_;
  if ($field =~ /^(?:entries)$/i) {
    return $self->SUPER::set('object', $value);
  } elsif ($field =~ /^(?:date|userHandle)$/i) {
    $self->{$field} = $value;
  } elsif ($field =~ /^(?:entry)$/) {
    confess "entry is not valid for this class, use entry";
  } else {
    return $self->SUPER::set($field, $value);
  }
}
###############################################################################
sub action ($$) {
  my($self, $actionData) = @_;

  print "in DeletedEntry action with edge $actionData->{edge}\n";
  if ($actionData->{edge} eq "abort") {
    # Do nothing but set the status, if we have aborted the deletion
    $self->set('status', 'ABORTED');
  } elsif ($actionData->{edge} eq "category") {
    my $date = $self->get('date');
    die "caught a delete edge without category"
      unless defined $actionData->{category};

    die "caught a delete edge without a date" unless defined $date;
    my(@entries);

    if ($date eq "last") {
      my $entry =
        $self->getDatabase()->getLastEntryWithCategory($self->get('userHandle'),
                                      $actionData->{category});
      push(@entries, $entry) if defined $entry;
    } else {
      @entries = $self->getDatabase()->
                 getEntriesOnDateWithCategory($self->get('userHandle'),
                                              $date,
                                              $actionData->{category});
    }
    if (@entries <= 0) {
      print "NO ENTRIES FOUND\n";
      $self->set('status', 'NOT FOUND');
      return $actionData;
    }
    $self->set(entries => \@entries);
    foreach my $entry (@entries) { $entry->remove(); }
  }
  # Always allow data to flow downward through chains of entry nodes.
  return $actionData;
}
###############################################################################
sub prettyPrintIRC ($$) {
  my($self, $now) = @_;

  return "Aborted.  No entry deleted." if ($self->status eq "ABORTED");
  return "Aborted.  No entry found to delete."
    if ($self->status eq "NOT FOUND");

  my $today = UnixDate($now, '%b %E');

  my $retStr = "Did " . $self->status . ".";

  my $entries = $self->get('entries');
  foreach my $entry (@{$entries}) {
  my($startTime, $endTime, $amountTime, $dateOccurred, $category) =
    $self->_getTimesAndCat($entry);

    $retStr .= "  Deleted entry in $category" if defined $category;
    $retStr .= ", which lasted for  $amountTime" if defined $amountTime;
    $retStr .= " (on $dateOccurred)" if $dateOccurred ne $today;
    $retStr .= " which had started at $startTime" if defined $startTime and
      not defined $amountTime;
    $retStr .= ".";
  }
  return $retStr;
}

1;
__END__

#
# Local variables:
# compile-command: "perl -I ../../../../Modules -c DeleteEntry.pm"
# End: