root/trunk/antimatter/tim/Modules/SFLC/TimeTracker/Output/Entry.pm

# Copyright (C) 2005, 2006   Software Freedom Law Center, Inc.
#  Author: Bradley M. Kuhn <bkuhn@softwarefreedom.org>
#
#  This software gives you freedom; it is licensed to you under version
#  3 of the GNU Affero General Public License.
#
#  This software is distributed WITHOUT ANY WARRANTY, without even the
#  implied warranties of MERCHANTABILITY and FITNESS FOR A PARTICULAR
#  PURPOSE.  See the GNU Affero General Public License for further
#  details.
#
# You should have received a copy of the GNU Affero General Public
# License, version 3 along with this software.  If not, see
# <http://www.gnu.org/licenses/>.
package SFLC::TimeTracker::Output::Entry;

use strict;
use warnings;

use base qw(SFLC::TimeTracker::Output);

use Lingua::EN::Inflect qw ( PL);
use Date::Manip;

sub getDatabase {
  return $SFLC::TimeTracker::Input::DATABASE;
}
###############################################################################
sub new {
  my($class) = shift;

  my %input = @_;
  if (defined $input{entry}) {
    $input{object} = { id => $input{entry}->get('id'),
                       userHandle => $input{entry}->get('userHandle'),
                       entryAsReceived => $input{entry}
                     };
    # Note that we keep around the entry as we received it.  We may
    #  be asked later to printout the entry after it is gone from the database.
  }
  my $self = SFLC::TimeTracker::Output::new($class, %input);
  return $self;
}
###############################################################################
sub get {
  my($self, $field) = @_;
  if ($field =~ /^(?:entry)$/) {
    # Be smart here.  First, see if the entry is in the database.  If it is,
    #  We want the freshest version of it we can.  It could have been deleted
    #  subsequent to the creation of this objec, however, so we have to 
    #  sometimes use the cached version.
    my $obj = $self->SUPER::get('object');
    my $dbEntry =
      $self->getDatabase()->getEntryById($obj->{userHandle}, $obj->{id});
    return (defined $dbEntry and ref $dbEntry) ? $dbEntry
                                   : $obj->{entryAsReceived};
  } else {
    return $self->SUPER::get($field);
  }
}
###############################################################################
sub action ($$) {
  my($self, $actionData) = @_;

  my $entry = $self->get('entry');
  my $userHandle = $entry->get('userHandle');

  print "in Entry action with edge $actionData->{edge}\n";
  if ($actionData->{edge} eq "abort") {
    $entry->remove();
    $self->set('status', 'ABORTED');
  } else {
    foreach my $key (keys %{$actionData}) {
      if ($entry->needs($key)) {
        $entry->set($key, $actionData->{$key});
      }
    }
  }
  # Always allow data to flow downward through chains of entry nodes.
  return $actionData;
}
###############################################################################
sub _getTimesAndCat ($$) {
  my($self, $entry) = @_;

  my $amountTime = (defined $entry->{amountTime}) ?
    Delta_Format($entry->{amountTime}, 1,
                 '%ht ' . PL("hour", $entry->{amountTime})) : "";
  # If we are going to say "0.0 hours, just redo it in minutes
  if ($amountTime =~ /^\s*0.0+\s+hour/) {
    $amountTime = Delta_Format($entry->{amountTime}, 1,
                               '%mt ' . PL("minute", $entry->{amountTime}));
  }
  # If we are going to say "0.0 minutes, just redo it in seconds
  if ($amountTime =~ /^\s*0.0+\s+minute/) {
    $amountTime = Delta_Format($entry->{amountTime}, 2,
                               '%st ' . PL("second", $entry->{amountTime}));
  }
  $amountTime =~ s/s\s*$//  if ($amountTime =~ /^\s*1.0\s+/);
  $amountTime = undef if $amountTime =~ /^\s*$/;

  my $category = $entry->get('category');
  $category = (defined $category) ? $category->prettyPrint() : "UNKNOWN";
  my $dateOccurred = UnixDate($entry->{dateOccurred}, '%b %E')
    if defined $entry->{dateOccurred};

  # FIXME: User Config fo rthe way time looks
  my $startTime = UnixDate($entry->{startTime}, '%i:%M%p')
    if defined $entry->{startTime};
  $startTime =~ s/^\s+// if defined $startTime;

  my $endTime = UnixDate($entry->{endTime}, '%i:%M%p')
    if defined $entry->{endTime};
  $endTime =~ s/^\s+// if defined $endTime;

  my $note = $entry->get('note');

  $category .= " (with note: " . $note . ")"
    if defined $note and $note !~ /^\s*$/;

  return ($startTime, $endTime, $amountTime, $dateOccurred, $category);
}
###############################################################################
sub prettyPrintIRC ($$) {
  my($self, $now) = @_;

  my $today = UnixDate($now, '%b %E');

  my($startTime, $endTime, $amountTime, $dateOccurred, $category) =
    $self->_getTimesAndCat($self->get('entry'));

  # FIXME: THese PL's don't actually work because amountTime is formatted
  #    as a Delta

  if ($self->status eq "ABORTED") {
    my $retStr = "Aborted entry";
    $retStr .= " that started at $startTime" if defined $startTime;
    $retStr .= " (it would have lasted for $amountTime)" if defined $amountTime;
    $retStr .= ".";
    return $retStr;
  }
  my $retStr = "Did " . $self->status . ".  ";


  my $type = $self->type;   my $status = $self->status;

  if ($type eq "completed"
      or ($type eq "new" and ($status =~ /^ADDED/
                                    or $status eq "ADJUSTED"))) {
    $retStr .= "Got $amountTime";
    $retStr .= " (on $dateOccurred)" if $dateOccurred ne $today;
    $retStr .= " in ${category}.";
  } elsif ($type eq "new" and $status eq "STARTED") {
    $retStr .= "You're in ${category} (as of ${startTime}).";
  } elsif ($type eq "modified") {
    $retStr .= "Work on ${category} now starts at $startTime";
    $retStr .= " (on $dateOccurred)" if $dateOccurred ne $today;
    $retStr .= ".";
  } elsif ($type =~ /abandoned$/) {
    $retStr .= "Work in ${category}, started at $startTime";
    $retStr .= " (on $dateOccurred)" if $dateOccurred ne $today;
    $retStr .= " has been abandoned.";
  } else {
    $retStr .= "REPORT THIS: output for $type not handled.";
  }
  return $retStr;
}

1;
__END__

#
# Local variables:
# compile-command: "perl -I ../../../../Modules -c Entry.pm"
# End: