root/trunk/antimatter/tim/Modules/SFLC/TimeTracker/Question/Category.pm

# Copyright (C) 2005   Software Freedom Law Center, Inc.
#  Author: Bradley M. Kuhn <bkuhn@softwarefreedom.org>
#
#  This software gives you freedom; it is licensed to you under version
#  3 of the GNU Affero General Public License.
#
#  This software is distributed WITHOUT ANY WARRANTY, without even the
#  implied warranties of MERCHANTABILITY and FITNESS FOR A PARTICULAR
#  PURPOSE.  See the GNU Affero General Public License for further
#  details.
#
# You should have received a copy of the GNU Affero General Public
# License, version 3 along with this software.  If not, see
# <http://www.gnu.org/licenses/>.
package SFLC::TimeTracker::Question::Category;

use strict;
use warnings;


require Exporter;
#use AutoLoader qw(AUTOLOAD);

use base qw(SFLC::TimeTracker::Question Exporter);


our @EXPORT_OK = ();

our @EXPORT = qw( );

our $VERSION = '0.01';

use Carp;
our $FREE_FORM_STRING = "__FREEFORM__";
our $REJECT_STRING = "__REJECT__";
our $EXISTING_STRING = "__EXISTING__";

sub new {
  my $class = shift;
  my $self = SFLC::TimeTracker::Question::new($class, @_);
  my %args = @_;
  $self->{originalCategory} = $args{category} if defined $args{category};
  $self->{resolutionData} = {};
  $self->{resolutionData}{answerType} = 'loopback';
  return $self;
}
sub setResolutionData {
  my $self = shift;

  $self->{resolutionData} = shift;
}
sub getResolutionData {
  my $self = shift;
  return %{$self->{resolutionData}};
}
###############################################################################
sub resolve ($$) {
  my($self, $answer) = @_;

  my $retVal = undef;

  my $number = $self->validateAnswer($answer);
  return "INVALID" unless defined $number;
  my $categoryID;
  my $rejected = 0;
  if ($self->{answers}{$number} eq $FREE_FORM_STRING) {
    $answer =~ s/^\s*$number\s+(.*)\s*$/$1/;
    $categoryID = $1;
    return "INVALID" unless $categoryID =~ /^\/([^\/\s]+\/)*[^\/\s]+$/;
    my $category = new SFLC::TimeTracker::Category(name => $categoryID);
    $categoryID = $category->get('id');
    $self->getDatabase()->setCategoryAlias($self->{userHandle},
             $self->{originalCategory}, $category)
      if defined $self->{originalCategory};
    print "Aliased \"$self->{originalCategory}\" to \"$categoryID\" if defined\n"
  } elsif ($self->{answers}{$number} eq $EXISTING_STRING) {
    $answer =~ /^\s*$number\s+(.*)\s*$/;
    my $categoryCandidate = $1;
    print "doing Existing! $answer$categoryCandidate\n";
    return "INVALID" unless $categoryCandidate =~ /^\/([^\/\s]+\/)*[^\/\s]+$/;
    $categoryID = $self->getDatabase()->categoryAliasLookup($self->{userHandle},
                                                            $categoryCandidate);
    if (not defined $categoryID) {
      return "UNKNOWN";
    }
  } elsif ($self->{answers}{$number} eq $REJECT_STRING) {
    $rejected = 1;
  } else {
    $categoryID = $self->{answers}{$number};
  }
  if ($rejected) {
    $self->setResolutionData({ answerType => 'abort'});
    return "REJECTED";
  } else {
    $self->getDatabase()->setCategoryAlias($self->{userHandle},
             $self->{originalCategory}, $categoryID)
      if defined $self->{originalCategory};
    print "Aliased \"$self->{originalCategory}\" to \"$categoryID\" if defined\n"
  }
  $self->setResolutionData({ answerType => 'category',
                             category => $categoryID});
  return "RESOLVED";
}
###############################################################################
sub freeFormReplacement {
  my($self, $ans) = @_;

  return "Enter your own new category by typing \"$ans /NEW/CAT\"";

}

sub rejectReplacement {
  my($self, $ans) = @_;

  return "Abort this entry";

}
sub existingReplacement {
  my($self, $ans) = @_;

  return "Enter an known, existing category not listed here";

}
sub formatResolveString ($$) {
  my($self, $string) = @_;

  my $superAnswer = $self->SUPER::formatResolveString($string);
  if (not defined $superAnswer) {
      return "Aborted." if $string eq "REJECTED";
      return "There is no known, existing category by that name." if $string eq "UNKNOWN";
      return "Ok, I am truly confused.  I got the answer, $string.";
    } else {
      return $superAnswer;
    }
}

1;
__END__

#
# Local variables:
# compile-command: "perl -I ../../../../Modules -c Category.pm"
# End: