root/trunk/antimatter/tim/Scripts/bot-run-check.plx

#!/usr/bin/perl

use strict;
use warnings;

use Unix::Syslog qw(:subs);
use Unix::Syslog qw(:macros);
use Date::Manip;

my $IRC_HOME = "/home/ircbot";
my $BOT_DIR = "$IRC_HOME/Bots";

my $PAGE_EMAIL = "page\@example.org";

{
  my %messageHistory;

  sub WarnLog ($$) {
    my($now, $message) = @_;

    syslog LOG_INFO, $message;

    my $lastTime = $messageHistory{$message};

    my $sendIt = 0;
    if (not defined $lastTime) {
      $sendIt = 1;
    } else {
      my $err;
      my $sinceLast = DateCalc($lastTime,"+ 10 minutes",\$err);
      $sendIt = 1 if ($now gt $sinceLast);
    }
    if ($sendIt) {
      open(SENDMAIL, "|/usr/sbin/sendmail -f root\@example.org -t");
      print SENDMAIL "To: $PAGE_EMAIL\nFrom: root\@example.org\n",
      "Subject: IRC, LOG\n\n$message\n.\n";
      close(SENDMAIL);
      if ($? != 0) {
        syslog LOG_INFO, "Unable to perform sendmail: $!";
      } else {
        $messageHistory{$message} = $now;
      }
    }
  }
}
###############################################################################
%ENV = ();
$ENV{PATH} = "/bin:/usr/bin";
$ENV{HOME} = "$IRC_HOME";
$ENV{USER} = $ENV{LOGNAME} ='ircbot';
$ENV{SHELL} = "/bin/bash";

chdir("$BOT_DIR/Scripts")
  or WarnLog(ParseDate("today"), "unable to change to $BOT_DIR: $!");

my %bots = (log => { pidFile => "$IRC_HOME/pids/log-bot.pid",
                     scriptFile => "$BOT_DIR/Scripts/logging-bot.plx" },
            tem => { pidFile => "$IRC_HOME/pids/temp-bot.pid",
                     scriptFile => "$BOT_DIR/Scripts/temp-bot.plx" },
            tim => { pidFile => "$IRC_HOME/pids/time-bot.pid",
                     scriptFile => "$BOT_DIR/Scripts/time-bot.plx" },
           sflc_log => { pidFile => "$IRC_HOME/pids/freenode-log-bot.pid",
                     scriptFile => "$BOT_DIR/Scripts/freenode-logging-bot.plx" }
);

foreach my $key (keys %bots) {
  my $pid;
  if (-f $bots{$key}{pidFile}) {
    open(PID_FILE, "<$bots{$key}{pidFile}")
     or WarnLog(ParseDate("today"), "unable to open $bots{$key}{pidFile}: $!");

    $pid = <PID_FILE>;
    close PID_FILE;
    chomp $pid;

    system("/bin/ps -p $pid > /dev/null 2>&1");
  }

  if ( (not defined $pid) or $pid eq "" or $? != 0) {
    unlink($bots{$key}{pidFile});
    system("/usr/bin/nohup /usr/bin/perl -I $BOT_DIR/Modules -I $BOT_DIR/Bot-BasicBot/lib  $bots{$key}{scriptFile} >> $IRC_HOME/logs/${key}.log 2>&1 &");
    WarnLog(ParseDate("today"), "unable to launch $key bot: $!")
      unless ($? == 0);
  }
}

###############################################################################
#
# Local variables:
# compile-command: "perl -c bot-run-check.plx"
# End:
#