root/trunk/apps/pdfdiff/pdfdiff.in

#!@PERL@ -w
#  pdfdiff, Version @VERSION@                                      -*- Perl -*-
#     This program is a a front-end script to use B::JVM::Kawa to generate
#     JVM bytecode for Perl programs
#
# Copyright (C) 2008  Bradley M. Kuhn.
# Copyright (C) 2008  Software Freedom Law Center, Inc.
#
#    This software gives you freedom; it is licensed to you under version 3
#    of the GNU General Public License, as published by the Free Software
#    Foundation.
#
#    This software is distributed WITHOUT ANY WARRANTY, without even the
#    implied warranties of MERCHANTABILITY and FITNESS FOR A PARTICULAR
#    PURPOSE.  See the GNU Affero General Public License for further
#    details.
#
#    You should have received a copy of the GNU General Public License,
#    version 3 with this software in the file GPLv3 in this directory.  If
#    not, see <http://www.gnu.org/licenses/>.

use File::Basename qw(&basename &dirname);
use Cwd;

require @PERL_VERSION_NEEDED@;

use strict;
use warnings;

use Getopt::Long qw(:config auto_help bundling);
use Pod::Usage;
use PDF::Extract::Text;
use File::Temp ();

my $DIFF_CMD  = '@DIFF@';
my $PDIFF_CMD = '@PDIFF@';
my $MELD_CMD = '@MELD@';

=head1 SYNOPSIS

pdfdiff [options] <old_file.pdf> <new_file.pdf>

General Options:

  --save-intermediates=TEMPLATE    Saves the text files generated.

Output Options:

 By default, output will be regular DIFF style.

  --options=OPTIONS    Add OPTIONS to diff/merge command.

 Three output styles are supported:

 DIFF
   Uses the system's 'diff' program, @DIFF@.
     --diff=DIFF_CMD           Run an alternative DIFF_CMD instead of @DIFF@.

 PDIFF
   Uses the @PDIFF@ program from a2ps to generate a Postscript markup.

     --pdiff=PSFILE_OUTPUT      Use "pdiff" to generate output to PSFILE_OUTPUT

 MELD
   Uses the GUI program, @MELD@ to merge the two versions.

     --meld                    Use @MELD@
     --meld-options=OPTIONS    Add OPTIONS to the pdiff command

=head1 DESCRIPTION

pdfdiff attempts to do anything it can to extract the text from two PDFs,
show you the differences, and try to help you merge the versions if you
want to.

=head1 OPTIONS

=over 8

=item B<--save-intermediates=TEMPLATE>

Save the text files generated before the diff for the old and new PDF.
The output is put in TEMPLATE-old.txt and TEMPLATE-new.txt, respectively.
TEMPLATE can include a path name.

=item B<--diff=DIFF_CMD>

Use DIFF_CMD instead of @DIFF@ when running the diff.


=item B<--pdiff>

Use @PDIFF@ to generate Postscript output differences.  Given a string
argument, POSTSCRIPT_OUTPUT, which will be the postscript output file.


=item B<--meld>

Use @MELD@.

=item B<--options>

Given a string argument, OPTIONS, those options will be passed to the
chosen diff command or merging process.

=item B<--verbose>

Be noisy about what is being done.  Note that this is very verbose.  It's a firehouse or nothing.

=item B<--help>

This help page.

=back

=cut

my($saveTemplate, $pdiffOutputFile, $extraDiffOptions,$diffCmd, $useMeld,
   $help, $verbose);

GetOptions("save-intermediates=s" => \$saveTemplate,
           "pdiff=s"              => \$pdiffOutputFile,
           "options=s"            => \$extraDiffOptions,
           "diff=s"               => \$diffCmd,
           "meld"                 => \$useMeld,
           "help"                 => \$help,
           "verbose"              => \$verbose
) or pod2usage(2);
pod2usage(-exitstatus => 0, -verbose => 2) if $help;
pod2usage("$0: takes exactly two files.\n")  if (@ARGV != 2);

foreach my $file (@ARGV) {
  pod2usage("$0: cannot read $file: $!")  unless (-r $file);
}

my($oldFile, $newFile) = @ARGV;

if ($verbose) {
  $PDF::OCR::Thorough::DEBUG = 1;
}

my($oldTextFile, $newTextFile, $oldFH, $newFH);

if ($saveTemplate) {
  $oldTextFile = "${saveTemplate}-old.txt";
  $newTextFile =  "${saveTemplate}-new.txt";
  $oldFH = new IO::File ">$oldTextFile" or 
    pod2usage("$0: cannot open $oldTextFile for writing: $!");
  $newFH = new IO::File ">$newTextFile" or 
    pod2usage("$0: cannot open $newTextFile for writing: $!");
} else {
  $oldFH = new File::Temp(TEMPLATE => 'oldXXXXXXXX',
                          UNLINK => 1, SUFFIX => '.txt', DIR => File::Spec->tmpdir);
  $oldTextFile = "$oldFH";
  $newFH = new File::Temp(TEMPLATE => 'newXXXXXXXXX',
                          UNLINK => 1, SUFFIX => '.txt', DIR => File::Spec->tmpdir);
  $newTextFile = "$newFH";
}

my $oldExtract = new PDF::Extract::Text(pdfFile => $oldFile)
  or die("cannot do PDF::OCR::Thorough on $oldFile");
my $newExtract = new PDF::Extract::Text(pdfFile => $newFile)
  or die("cannot do PDF::OCR::Thorough on $newFile");

my $oldText = $oldExtract->getText();
my $newText = $newExtract->getText();

print $oldFH $oldText;
print $newFH $newText;

$oldFH->close();
$newFH->close();

my(@commands);

if ($pdiffOutputFile) {
  my $list = [ $PDIFF_CMD, "-o", $pdiffOutputFile ];
  push(@{$list}, $extraDiffOptions) if $extraDiffOptions;
  push(@{$list}, $oldTextFile, $newTextFile);
  push(@commands, $list);
}
if ($useMeld) {
  my $list = [ $MELD_CMD ];
  push(@{$list}, $extraDiffOptions) if $extraDiffOptions;
  push(@{$list}, $oldTextFile, $newTextFile);
  push(@commands, $list);
}

unless ($pdiffOutputFile or $useMeld) {
  my $list = [ ($diffCmd ? $diffCmd : $DIFF_CMD) ];
  push(@{$list}, $extraDiffOptions) if $extraDiffOptions;
  push(@{$list}, $oldTextFile, $newTextFile);
  push(@commands, $list);
}
foreach my $cmd (@commands) {
  system(@{$cmd});
}
$oldFH = $newFH = undef;

exit 0;